plugins {
    id 'com.android.application'
    id 'kotlin-android'
    id 'com.google.android.filament-tools'
}

project.ext.isSample = true

kotlin {
    jvmToolchain(versions.jdk)
}

filament {
    materialInputDir = project.layout.projectDirectory.dir("src/main/materials")
    materialOutputDir = project.layout.projectDirectory.dir("src/main/assets/materials")
}

clean.doFirst {
    delete "src/main/assets"
}

android {
    namespace 'com.google.android.filament.textureview'

    compileSdkVersion versions.compileSdk
    defaultConfig {
        applicationId "com.google.android.filament.textureview"
        minSdkVersion versions.minSdk
        targetSdkVersion versions.targetSdk
    }

    // NOTE: This is a workaround required because the AGP task collectReleaseDependencies
    //       is not configuration-cache friendly yet; this is only useful for Play publication
    dependenciesInfo {
        includeInApk = false
    }

    // We use the .filamat extension for materials compiled with matc
    // Telling aapt to not compress them allows to load them efficiently
    aaptOptions {
        noCompress 'filamat', 'ktx'
    }

    compileOptions {
        sourceCompatibility versions.jdk
        targetCompatibility versions.jdk
    }
}

dependencies {
    implementation deps.kotlin
    implementation project(':filament-android')
}