plugins {
    id 'com.android.application'
    id 'kotlin-android'
    id 'filament-tools-plugin'
}

project.ext.isSample = true

filamentTools {
    materialInputDir = project.layout.projectDirectory.dir("src/main/materials")
    materialOutputDir = project.layout.projectDirectory.dir("src/main/assets/materials")
}

clean.doFirst {
    delete "src/main/assets"
}

android {
    namespace 'com.google.android.filament.hellocam'

    compileSdkVersion versions.compileSdk
    defaultConfig {
        applicationId "com.google.android.filament.hellocamera"
        minSdkVersion 23
        targetSdkVersion versions.targetSdk
    }

    // NOTE: This is a workaround required because the AGP task collectReleaseDependencies
    //       is not configuration-cache friendly yet; this is only useful for Play publication
    dependenciesInfo {
        includeInApk = false
    }

    // We use the .filamat extension for materials compiled with matc
    // Telling aapt to not compress them allows to load them efficiently
    aaptOptions {
        noCompress 'filamat', 'ktx'
    }
}

dependencies {
    implementation deps.kotlin
    implementation deps.androidx.core
    implementation project(':filament-android')
}